miércoles, 29 de septiembre de 2010

Ansys en una Cáscara de Nuez: Gradiente Térmico Usando "Body Loads"

En este tutorial veremos la forma más sencilla (usando "body loads") de imponer como condición de contorno un gradiente térmico en una placa para ver su respuesta estructural.

Usamos Ansys + CivilFEM. Este último no es necesario para aplicar el gradiente.

Determinamos la deformada, la distribución de temperaturas y las tensiones equivalentes de Von Mises.

Datos del problema

Espesor: 60 cm.
Dimensiones: 5 x5 m^2
Hormigón: C25/30
Armado: S500
Un lado empotrado.
Temperaturas impuestas en las caras: 125ºC y 25ºC.


Comandos APDL

FINISH
~CFCLEAR,,1
! --------------------------------------
/TITLE, Gradiente termico en una placa
! --------------------------------------
! Unidades y normas
! --------------------------------------
~UNITS,SI
! --------------------------------------
! Parámetros
recub = 0.03 ! Recubrimiento
e1= 0.6 ! Espesor de la placa
! --------------------------------------
/prep7
! --------------------------------------
! Materiales
~CFMP,1,LIB,CONCRETE,EC2,C25/30,0,0,0 ! Mat 1: Hormigón C25/30
~CFMP,2,LIB,REINF,EC2,S500,0,0,0 ! Mat 2: Acero para armado
! --------------------------------------
! Secciones y propiedades reales
! --------------------------------------
!Definimos vértices de placa de hormigón armado
~shlrnf,1,e1,1,2,recub ! Vértice 1
! Propiedades de placas de hormigón
~BMSHPRO,1,SHELL,1,1,1,1,63,,,,Placa de hormigon
! --------------------------------------
! Tipos de elementos
! --------------------------------------
ET,1,shell63
! --------------------------------------
! Geometría
! --------------------------------------
k,1,0,0,0
k,2,5,0,0
k,3,5,5,0
k,4,0,5,0
l,1,2
l,2,3
l,3,4
l,4,1
al,1,2,3,4
! --------------------------------------
! Mallado
! --------------------------------------
mshkey,1 ! Mallado mapeado
esize,10 !tamaño de elemento
type,1 $ mat,1 $ real,1
amesh,all
! --------------------------------------
! Visualización
! --------------------------------------
/eshape,1 $ eplot ! muestra los elementos con su verdadera forma
/eshape,0 $ eplot ! Vuelve a la representación esquemática
! --------------------------------------
! Condiciones de contorno y carga térmica
! --------------------------------------
! Empotramiento
dl,4,,all,0
! Carga térmica - Gradiente de 100ºC
bfe,all,temp,1,25,25,25,25
bfe,all,temp,5,125,125,125,125
! --------------------------------------
/solu
solve
finish
/post1
! Define el data set de ANSYS y la alternativa de CivilFEM
! a ser leída del fichero de resultados de ANSYS y CivilFEM
~cfset,,1
! --------------------------------------
! Distribución de temperaturas
! --------------------------------------
/eshape,1
PLESOL, BFE,TEMP, 0,1.0 ! Sin modelo original
! PLESOL, BFE,TEMP, 1,1.0 ! Con modelo original
! --------------------------------------
! Deformada
! --------------------------------------
/eshape,1
pldisp,1 ! Con modelo original
! --------------------------------------
! Distribución de tensiones Von Mises
! --------------------------------------
! PLESOL, S,EQV, 1,1.0 ! Con modelo original
PLESOL, S,EQV, 0,1.0 ! Sin modelo original
! --------------------------------------



Resultados

Distribución de temperaturas en la placa debidas al gradiente:


Deformada debida a la carga térmica:


Los planos de la placa sometidos a más temperatura dilatan más que los más fríos.

Distribución de tensiones equivalentes de Von Mises:


Volver al índice...

No hay comentarios:

Publicar un comentario